AsyncHeaderDataModel

import bb.cascades 1.2
import bb.cascades.datamanager 1.2
Page {
    content: Container {
        layout: StackLayout {
        }
        ListView {
            property string imagePath: app.imagePath
            layout: StackListLayout {
                headerMode: ListHeaderMode.Sticky
            }
            id: myListView
            dataModel: dm
            listItemComponents: [
                ListItemComponent {
                    type: "header"
                    Header {
                        title: ListItemData.header
                    }
                },
                ListItemComponent {
                    type: ""
                    StandardListItem {
                        title: ListItemData.firstname + " " + ListItemData.lastname
                        imageSource: ListItemData.image
                        description: ListItemData.title
                    }
                }
            ]
        }
        attachedObjects: [
            // an example to demonstrate how to use an AsyncHeaderDataModel
            AsyncHeaderDataModel {
                id: dm
                cacheSize: 200
                // can use any query that implements the HeaderDataQuery interface
                // SqlHeaderDataQuery is the default implementation provided with the library
                query: SqlHeaderDataQuery {
                    source: "sql/contacts1k.db"
                    query: "select id, firstname, lastname, title, image, active, revision_id " +
                           "from contact order by lastname, firstname"
                    headerQuery: "select substr(lastname, 1, 1) as header, count(*) " +
                           "from contact group by header"
                    countQuery: "select count(*) from contact"
                    keyColumn: "id"
                    revisionColumn: "revision_id"
                    revisionQuery: "select revision_id from revision"
                    onError: console.log("SQL query error: " + code + ", " + message)
                }
                onLoaded: console.log("initial model data is loaded")
            }
        ]
    }
    onCreationCompleted: {
        dm.load();
    }
}